過去の桐井戸端ＢＢＳ　（桐ver.９）
29165 検索条件登録をいく通りもしたいのですがスマートな方法はありますか 桐初心者です 2005/02/26-12:27
いつも参考にさせていただいております．
ありがとうございます

今回の質問はかなり初歩的なことですがよろしくお願いします．

［出荷年］，［出荷月］，［出荷日］，［顧客名］，［品名］，［数量］，［輸送方法］と7つの項目があります．
検索条件を入力するフォームを作りました．
編集対照表はなしです．該当する項目のソースはすべて変数にしました.
&出荷年，&出荷月　…　,&輸送方法　です
検索方法としては，必要な項目だけしかも部分一致でもOKとしたいのですが，

出荷年と出荷月だけを指定するときは
　検索条件登録　条件名="検索条件名"，{[出荷年]=&出荷年,[出荷月]=&出荷月}
　絞込み　条件名="検索条件名"

出荷年と出荷月と顧客名を指定するときは
　検索条件登録　条件名="検索条件名"，{[出荷年]=&出荷年,[出荷月]=&出荷月,
[顧客名]*&顧客名*}
　絞込み　条件名="検索条件名"

と言う風にすべて書かなくてはならないのでしょうか？
何かいい方法はありませんか

よろしくお願いいたします．

29166 Re:検索条件登録について 宮城 2005/02/26-13:47
記事番号29165へのコメント
桐初心者ですさん、こんにちは。

検索条件は複数個記憶できますので、最初のを「年月検索」、次のを
「年月顧客検索」とかの検索条件名にすれば、次からはいきなり
「絞込み　条件名」でいけますが、そういうことではないのですか？

29167 Re:検索条件登録について 桐初心者です 2005/02/26-14:15
記事番号29166へのコメント
宮城さん 早速のお答えありがとうございます

説明不足でした．
確かに言われるとおりですが，この方法だと7項目あれば
２の７乗で128通り作らなければならないのではないでしょうか？
もっとスマートな方法はないでしょうか？

　　　　　　　　　　　　　　　　　　　　よろしくお願いいたします
29168 Re:検索条件登録について 宮城 2005/02/26-15:19
記事番号29167へのコメント
>確かに言われるとおりですが，この方法だと7項目あれば
>２の７乗で128通り作らなければならないのではないでしょうか？
>もっとスマートな方法はないでしょうか？

そういうことでしたら、私なら迷うことなく表操作をナマで覚えていただきます。
ワンタッチボタンを作れという要求はきっぱりことわります。

年で絞込み、さらに月で絞込み、もっと絞り込みたいならお好きなように。実にシンプルです。
29169 Re:検索条件登録について 尾形 2005/02/26-15:42
記事番号29165へのコメント
どうもこんにちは

条件　(&出荷年>0)　絞り込み　[出荷年]{=&出荷年}
条件　(&出荷月>0)　絞り込み　[出荷月]{=&出荷月}
条件　(&顧客名<>"")絞り込み　[顧客名]{=*&顧客名*}

検索条件登録で一回で絞り込みしようとせず
ばらばらに書いたらどうですか


29173 ありがとうございます 桐初心者です 2005/02/26-17:18
記事番号29169へのコメント
尾形さんありがとうございます
そうですね
そのとおり
ありがとうございました
29188 Re:検索条件登録について アックン 2005/02/28-18:16
記事番号29165へのコメント
桐初心者ですさん、こんにちは。
フォームの見本をアップしました。
桐のバージョンが対応してないときはすみません。(V9-2005対応)


こういうときは、「コマンド」コマンドを使うと可能になります。
慣れないうちはダブルクォーテーションの位置やら数で苦労しますけど、
意味不明なところは続けて質問してください。

20050228検索条件登録メイン.kev
---------------------------------
名札 メイン

＊

手続き定義開始　コマンドボタン_1::マウス左クリック(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&
フラグ，参照　長整数　&処理中止)
　method @フォーム.更新モード設定( 0 )
　フォーム呼び出し　"20050228検索条件登録モーダル"
手続き定義終了
---------------------------------
（続く）

29189 Re:検索条件登録について アックン 2005/02/28-18:18
記事番号29188へのコメント
（続き）
20050228検索条件登録モーダル.kev
----------------------------------------------
名札 メイン
　var 整数{ &出荷年 , &出荷月 , &出荷日 }
　var 数値{ &数量 }
　var 文字列{ &顧客名 , &品名 , &輸送方法 }
＊

手続き定義開始　bボタン::マウス左クリック(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ，参照　長整数　&処理中止)
　method @フォーム.更新モード設定( 0 )
　編集表 "20050228検索条件登録"
　コマンド \
"検索条件登録　条件名=""test"",{" \
+#cond( &出荷年 , "[出荷年]=&出荷年 , " ) \
+#cond( &出荷月 , "[出荷月]=&出荷月 , " ) \
+#cond( &出荷日 , "[出荷日]=&出荷日 , " ) \
+#cond( &顧客名 , "[顧客名]{*"+&顧客名+"*} , " ) \
+#cond( &品名 , "[品名]=&品名 , " ) \
+#cond( &数量 , "[数量]=&数量 ," ) \
+#cond( &輸送方法 , "[輸送方法]=&輸送方法" ) \
+" }"
　絞込み　条件名="test"　
　if( .not&選択件数 )
　　　確認 "該当なし"
　　　絞り込み解除　1
　end
手続き定義終了

手続き定義開始　フォーム::フォーム開始(長整数　&表番号)
　method @フォーム.更新モード設定( 2 )
手続き定義終了

手続き定義開始　bボタン_1::マウス左クリック(長整数　&マウス位置[2]，長整数　&明細番号，長整数　&フラグ，参照　長整数　&処理
中止)
　method @フォーム.更新モード設定( 0 )
　編集表 "20050228検索条件登録"
　絞り込み解除　1
手続き定義終了
-----------------------------------

戻る